home *** CD-ROM | disk | FTP | other *** search
/ START Magazine / START VOL 4 NO 1.st / POGOSRC.ARC / STCLINE.ASM < prev    next >
Encoding:
Assembly Source File  |  1985-11-20  |  3.4 KB  |  170 lines
  1. ;stcline.asm - fetch parameters from pogo parameter pointer and
  2. ;clip line before calling fast line drawing routine in stline.asm
  3.  
  4.     dseg
  5.     public    _in_graphics
  6.     public _cscreen
  7.     public lcolor
  8.  
  9.     cseg
  10.     public _flashred
  11.     public    _to_graphics
  12.     public    drawcolr
  13.  
  14.     public _pline
  15. color equ -20
  16. x1    equ -16
  17. y1    equ -12
  18. x2    equ -8
  19. y2    equ -4
  20.  
  21.         
  22. _pline:    
  23.     ;1st make sure in graphics mode.
  24.     move.w    _in_graphics,d0
  25.     bne        gotg
  26.     jsr        _to_graphics
  27. gotg
  28.     move.l    4(sp),a0    ;fetch parameter pointer.
  29.     movem.l d2/d3/d4/d5/d6/d7,-(sp)    ;save C registers we need to use
  30.  
  31. ;now move all parameters where drawcolr line routine expects them
  32.     move.w    color(a0),d0
  33.     and.w    #15,d0    ;make sure color is 0 to 15
  34.     move.w    d0,lcolor
  35.     move.w x1(a0),d4
  36.     move.w y1(a0),d5
  37.     move.w x2(a0),d6
  38.     move.w y2(a0),d7
  39. ;make sure x1 <= x2
  40.     cmp.w   d6,d4   ; Swap axes if x2<x1
  41.     ble.s   cswapped
  42.     exg     d4,d6
  43.     exg     d5,d7
  44. cswapped:        
  45.  
  46. ;now do gnarly clipping...
  47. ;clip against left side (x < 0)
  48.     tst.w    d6        ;right side off-screen???
  49.     bmi        clippedout
  50.     tst.w    d4
  51.     bpl        rightclip
  52. ;here 1st endpoint is off screen, 2nd endpoint on screen.  
  53.     move.w    d7,d1
  54.     sub.w    d5,d1        ;d1 = delta y
  55.     muls    d4,d1        
  56.     move.w    d6,d0
  57.     sub.w    d4,d0
  58.     divs    d0,d1
  59.     sub.w    d1,d5
  60. ;y0 += (windowX0-x0)*dy/dx
  61. ;y0 -= x0*dy/dx
  62.     clr.w    d4
  63.  
  64. rightclip:
  65.     move.w    #319,d0        ;d0 is right edge of window
  66.     cmp.w    d4,d0
  67.     bmi        clippedout    ;left end of line past right edge of screen
  68.     sub.w    d6,d0
  69.     bpl        vclip
  70. ;here 2nd endpoint is off screen to right, 1st endpoint on screen.  
  71.     move.w    d7,d1
  72.     sub.w    d5,d1
  73.     muls    d0,d1
  74.     move.w    d6,d0
  75.     sub.w    d4,d0
  76.     divs    d0,d1
  77.     add.w    d1,d7
  78. ;y1 += (windowX1-x1)*dy/dx
  79.     move.w    #319,d6
  80.  
  81. vclip:        ;do vertical part of clipping
  82.     cmp.w    d7,d5
  83.     ble        firstup
  84. ;ok, here the second endpoint is less than the 1st y-wise
  85.  
  86.     tst.w    d5        ;bottom side off-screen???
  87.     bmi        clippedout
  88.     tst.w    d7
  89.     bpl        downclip
  90. ;here 1st endpoint is off screen, 2nd endpoint on screen.  
  91.     move.w    d4,d1
  92.     sub.w    d6,d1        ;d1 = delta x
  93.     muls    d7,d1        
  94.     move.w    d5,d0
  95.     sub.w    d7,d0
  96.     divs    d0,d1
  97.     sub.w    d1,d6
  98. ;x0 += (windowY0-y0)*dx/dy
  99. ;x0 -= y0*dx/dy
  100.     clr.w    d7
  101.  
  102. downclip:
  103.     move.w    #199,d0        ;d0 is bottom edge of window
  104.     cmp.w    d7,d0
  105.     bmi        clippedout    ;left end of line past right edge of screen
  106.     sub.w    d5,d0
  107.     bpl        doline
  108. ;here 2nd endpoint is off screen to bottom, 1st endpoint on screen.  
  109.     move.w    d4,d1
  110.     sub.w    d6,d1
  111.     muls    d0,d1
  112.     move.w    d5,d0
  113.     sub.w    d7,d0
  114.     divs    d0,d1
  115.     add.w    d1,d4
  116. ;x1 += (windowY1-y1)*dx/dy
  117.     move.w    #199,d5
  118.  
  119.     bra        doline
  120.  
  121. firstup:    ;here the 1st endpoint is less than the second
  122.     tst.w    d7        ;bottom side off-screen???
  123.     bmi        clippedout
  124.     tst.w    d5
  125.     bpl        downclip1
  126. ;here 1st endpoint is off screen, 2nd endpoint on screen.  
  127.     move.w    d6,d1
  128.     sub.w    d4,d1        ;d1 = delta x
  129.     muls    d5,d1        
  130.     move.w    d7,d0
  131.     sub.w    d5,d0
  132.     divs    d0,d1
  133.     sub.w    d1,d4
  134. ;x0 += (windowY0-y0)*dx/dy
  135. ;x0 -= y0*dx/dy
  136.     clr.w    d5
  137.  
  138. downclip1:
  139.     move.w    #199,d0        ;d0 is bottom edge of window
  140.     cmp.w    d5,d0
  141.     bmi        clippedout    ;left end of line past right edge of screen
  142.     sub.w    d7,d0
  143.     bpl        doline
  144. ;here 2nd endpoint is off screen to bottom, 1st endpoint on screen.  
  145.     move.w    d6,d1
  146.     sub.w    d4,d1
  147.     muls    d0,d1
  148.     move.w    d7,d0
  149.     sub.w    d5,d0
  150.     divs    d0,d1
  151.     add.w    d1,d6
  152. ;x1 += (windowY1-y1)*dx/dy
  153.     move.w    #199,d7
  154.  
  155.  
  156. doline:
  157.     jsr drawcolr
  158. clippedout:
  159.     movem.l    (sp)+,d2/d3/d4/d5/d6/d7
  160.     rts
  161.  
  162.  
  163. allregs    reg    a0-a6/d0-d7
  164.  
  165. flashred
  166.     movem.l    allregs,-(sp)
  167.     jsr    _flashred
  168.     movem.l    (sp)+,allregs
  169.     rts
  170.